Generisk formel
=MAXIFS(sales,dates,">="&G4,dates,"<="&EOMONTH(G4,0))
Resumé
For at finde den maksimale værdi i en given måned kan du bruge MAXIFS-funktionen eller et af de andre alternativer nedenfor. I det viste eksempel er formlen i G5:
=MAXIFS(sales,dates,">="&G4,dates,"<="&EOMONTH(G4,0))
Hvor salg (D5: D15), datoer (B5: B15) og værdier (C5: C15) er navngivet intervaller.
Forklaring
MAXIFS-funktionen kan finde den maksimale værdi i et interval baseret på et eller flere kriterier. I det viste eksempel bruger vi MAXIFS til at finde den maksimale salgsværdi baseret i en given måned ved "parentes" datoer mellem den første dag i måneden og den sidste dag i måneden. De første kriterier kontrollerer, om datoer er større end eller lig med den første i måneden:
dates,">="&G4,dates // first of month
Bemærk: vi antager, at dato i G4 er en "første måned" -dato.
Det andet kriterium kontrollerer, om datoer er mindre end eller lig med den sidste i måneden, beregnet med EOMONTH-funktionen:
dates,"<="&EOMONTH(G4,0) // last of month
Når begge kriterier returnerer SAND, er datoen i den givne måned, og MAXIFS returnerer maksimumværdien af datoer, der opfylder kriterierne.
Alternative formler
Hvis din version af Excel ikke indeholder MAXIFS-funktionen, er der andre muligheder. En mulighed er en simpel matrixformel baseret på MAX- og IF-funktionerne:
(=MAX(IF(TEXT(dates,"my")=TEXT(G4,"my"),sales)))
Bemærk: Dette er en matrixformel og skal indtastes med med kontrol + skift + enter.
En anden mulighed er at bruge AGGREGATE-funktionen som denne:
=AGGREGATE(14,6,sales/(TEXT(dates,"my")=TEXT(G4,"my")),1)
Begge muligheder ovenfor bruger en enklere metode til test af datoer baseret på TEKST-funktionen, der bruger et talformat til at udtrække måned og år fra en dato. TEKST-funktionen kan ikke bruges sådan i MAXIFS-funktionen, fordi MAXIFS kræver et interval. Disse alternative tilgange forklares mere detaljeret her.
Den maksimale klient
For at hente den klient, der er knyttet til den maksimale værdi i en given måned, er formlen i G6:
(=INDEX(clients,MATCH(1,(sales=G5)*(TEXT(dates,"my")=TEXT(G4,"my")),0)))
Dette er en matrixformel og skal indtastes med med kontrol + skift + enter.
Ideen her er, at vi allerede kender den maksimale værdi i en måned (G5), og at vi kan bruge denne værdi som en "nøgle" til at slå klienten op. Bemærk, at vi skal gentage den logik, der bruges til at isolere værdier i den givne måned, for at undgå en falsk match i en anden måned.
Ligesom de ovennævnte alternativer bruger denne formel også en forenklet test til datoer baseret på TEKST-funktionen. Læs mere om INDEX og MATCH med flere kriterier her.
For en alt-i-en-formel skal du erstatte G5 med en af formelindstillingerne beskrevet ovenfor for at bestemme den maksimale værdi i en given måned.
